Current Release

This documentation covers the latest release of VIVO, version 1.15.x.
If you are able to help contribute to this documentation, please contact vivo at lyrasis dot org
Looking for another version? See all documentation.

Note that these are CONSTRUCT queries designed to create a small Jena model for export as a whole after a series of queries has been run.  The PERSON_URI variable is substituted by VIVO at runtime.

grantAwardedBy.sparql
PREFIX core: <http://vivoweb.org/ontology/core#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

CONSTRUCT {
     ?awardingOrganization rdfs:label ?label 
} WHERE {
    {
      {PERSON_URI core:relatedBy ?investigatorRole .
       ?investigatorRole a core:PrincipalInvestigatorRole
      }
        union
      {PERSON_URI core:relatedBy ?investigatorRole .
       ?investigatorRole a core:CoPrincipalInvestigatorRole
      }   
     }
     
     ?investigatorRole core:relatedBy ?grant .
     ?grant a core:Grant .
     ?grant core:assignedBy ?awardingOrganization .
     ?awardingOrganization a foaf:Organization .
     ?awardingOrganization rdfs:label ?label 
}
grants.sparql
PREFIX core: <http://vivoweb.org/ontology/core#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

CONSTRUCT {
     ?grant ?property ?object .
     ?investigatorRole core:relatedBy ?grant .
} WHERE {
     {
       { PERSON_URI core:relatedBy ?investigatorRole .
         ?investigatorRole a core:PrincipalInvestigatorRole
       }
         union
       { PERSON_URI core:relatedBy ?investigatorRole .
         ?investigatorRole a core:CoPrincipalInvestigatorRole
       }   
     }
     
     ?investigatorRole core:relatedBy ?grant .
     ?grant a core:Grant .
     ?grant ?property ?object 
}
  • No labels

All content on the LYRASIS Wiki is licensed under the CC BY (Attribution) license, unless otherwise noted.